@echo off

REM 管理者で実行してるかの判定 openfiles自体に意味はないです
openfiles > NUL 2>&1 
if NOT %ERRORLEVEL% EQU 0 goto NotAdmin 
goto AdminOK
 
:NotAdmin 
echo 管理者権限で実行してください
pause
exit 0

:AdminOK

REM 「管理者で実行」でパスが変わってしまうのでおまじない
cd /d %~dp0

REM
REM ShotNavi W1-FW_PLUS PC TOOL Setup
REM

REM CP210xのドライバが入っているか確認
echo CP210xのドライバがインストールされているか確認します。

REM 見つかったらFOUNDへ飛ぶ
for /F "usebackq tokens=1,2,*" %%I in (`driverquery 2^>nul`) do if "%%I"=="silabenm" goto FOUND
REM 見つからなかったのでそのままCP210Xインストーラに
echo;
echo CP210xのドライバが見つかりませんでした。インストールを実行します。

REM 32bit 64bit を判別して それぞれのインストーラーを起動
set REGKEY=HKEY_LOCAL_MACHINE\System\CurrentControlSet\Control\Session Manager\Environment
set REGVALUE=PROCESSOR_ARCHITECTURE
set PA=
set CP210XPATH=.\CP210x_Windows_Drivers\
for /F "usebackq tokens=1,2,*" %%I in (`reg query "%REGKEY%" /v %REGVALUE% 2^>nul`) do if "%%I"=="%REGVALUE%" set PA=%%K
if "%PA%"=="x86" (
	echo;
	echo CP210xの32bit版ドライバのインストールを実行します。
	%CP210XPATH%CP210xVCPInstaller_x86.exe
) else if "%PA%"=="AMD64" (
	echo;
	echo CP210xの64bit版ドライバのインストールを実行します。
	%CP210XPATH%CP210xVCPInstaller_x64.exe
) else if "%PA%"=="IA64" (
	echo;
	echo CP210xの64bit版ドライバのインストールを実行します。
	%CP210XPATH%CP210xVCPInstaller_x64.exe
) else (
	echo;
	echo OSの 32bit/64bit 判定ができませんでした。手動でインストールしてください。
	echo;
	pause
	exit
)

:INSTMESSAGE
REM インストール後のメッセージ
echo;
echo アンインストールの際、ShotNavi W1-FW_PLUS PCツールのアンインストールでは、ドライバは同時に削除されません。
echo;
pause
goto END

:FOUND
echo;
echo CP210xのドライバーのインストールを確認しました。

:END
echo;

REM つづいて SN_W1-FW_PLUS PC Tool のインストールへ
echo;
echo ShotNavi W1-FW PC Tool のインストールを実行します。
.\SN_W1-FW_PLUS\setup.exe

